adding an exp cut off to my simple script

[Enuch]

I have a very simple script I'm using at the moment and was wondering one if its possible to add into a script a function where the script checks what my fried status is, and if I am fried or numbed pauses until I am clear as a bell and resumes. The script in question I have is

loop:
put get 1 shaft from my cape
pause 1
put cut my shaft with my stil
pause 40
put cut nock in my shaft with my stil
pause 1
put cut nock in my shaft with my stil
pause 20
put put shaft in barrel
pause 1
goto loop



Would anyone know if what I am asking is possible and if so could you provide a little guidance into what I need to do to adjust my script?

[Tgo01]

It would probably be easier to download lich and make this into a lich script:



loop{
(wait_until { percentmind == 0 }) if(percentmind > 89)
waitrt?
fput "get 1 shaft from my cape"
sleep 1
fput "cut my shaft with my stil"
sleep 1
waitrt?
fput "cut nock in my shaft with my stil"
sleep 1
waitrt?
fput "cut nock in my shaft with my stil"
sleep 1
waitrt?
fput "put shaft in barrel"
sleep 1
}


I haven't written a script in stormfront in forever so I forget how to do it. I know there is no specific way to check for mind status in stormfront so you would probably have to input the exp command and then have the script check for the line about your experience status to see if you're numbed or fried.

[TheBastardOfStark]

this should work




start:
put get 1 shaft from my cape
pause 1
put cut my shaft with my stil
pause 40
put cut nock in my shaft with my stil
pause 1
put cut nock in my shaft with my stil
pause 20
put put shaft in barrel
pause 1
goto checkexp

checkexp:
put exp
match "start" "clear as a bell"
match "start" "fresh and clear"
match "start" "clear"
match "start" "muddled"
match "rest" "becoming numbed"
match "rest" "numbed"
match "rest" "completely saturated"
match "rest" "must rest"
matchwait

rest:
pause 180
goto checkexp

[Enuch]

Thanks both, going to test yours out stark, and if it works, watch out for some smoochies your way!

[Enuch]

got this message after running the script when it checked my exp

s>exp
Script error[match label "start" not found] near line 17
[script aborted]
Level: 6 Deeds: 0
Experience: 45309 Death's Sting: None
Exp. until next: 9691 Recent Deaths: 0
Mental TPs: 10 Fame: 13117
Physical TPs: 39 Mana: 24/24 max

Your mind is completely saturated. It is imperative that you rest immediately!
s>

[Enuch]

I have lich as well, I just have the tech saavy of a tightly coiled pile. Would I copy and paste what you have Tgo?

[Wrathbringer]

I have lich as well, I just have the tech saavy of a tightly coiled pile. Would I copy and paste what you have Tgo?

omg lol I'm using that.

[AestheticDeath]

Your problem in the reg script was the quotation marks.

[AestheticDeath]

try this one with no quotes

start:
put get 1 shaft from my cape
pause 1
put cut my shaft with my stil
pause 40
put cut nock in my shaft with my stil
pause 1
put cut nock in my shaft with my stil
pause 20
put put shaft in barrel
pause 1
goto checkexp

checkexp:
put exp
match start clear as a bell
match start fresh and clear
match start clear
match start muddled
match rest becoming numbed
match rest numbed
match rest completely saturated
match rest must rest
matchwait

rest:
pause 180
goto checkexp

[AestheticDeath]

also, does the wait command not replace any kind of pause x seconds? i thought for some reason wait, just waits till you don't have RT and then moves on to next step

[AestheticDeath]

and... could actually replace the check block with this one I think


checkexp:
put exp
match start clear
match start muddled
match rest numbed
match rest completely saturated
match rest must rest
matchwait

[AestheticDeath]

aaannnddd I found this script I got from someone if you want to use it after you finish your 500 ranks


#.super fletcher
echo The Super Fletching Script - Arrows version
echo copywrite 2005 Keelty k'Adair
echo
echo Make sure all your supplies, with the exception of paintsicks for banding, are in one container
echo If banding with paintsticks, put the paintsticks in your second container
echo Check the flipping section to set your style preference
echo Check the measure section so that the Bow and Bow Container are correct for your equipment
echo
echo enter 'Yes' when you're set
waitfor A good positive attitude never hurts.

if_1 goto toolok
toolok:
if_2 goto suppok
suppok:
if_3 goto storeok
storeok:
if_4 goto paintok
paintok:
if_5 goto stickok
stickok:
if_6 goto headok
headok:
if_7 goto checkshaft

echo
echo Usage is fletch {cutting tool} {supplies container} {container for finished arrows} {paint? yes/no} {banding? yes/no} {Drilling and adding a head? yes/no} (scribe? yes/no}
echo
echo example fletch dagger bag cloak no yes yes no
echo
exit

#Check supplies

checkshaft:
put tap sha in my %2
match noshaft What were
match checkglue You tap
matchwait

checkglue:
pause 2
put tap glue in my %2
match noglue What were
match checkfletching You tap
matchwait

checkfletching:
pause 2
put tap fle in my %2
match nofletching What were
match check4%4 You tap
matchwait

check4yes:
pause 2
put tap paint in my %2
match nopaint What were
match check5%5 You tap
matchwait

check4no:
goto check5%5

check5yes:
pause 2
put tap paints in my %3
match nopaintstick What were
match check6%6 You tap
matchwait

check5no:
goto check6%6

check6yes:
pause 2
put tap drill in my %2
match nodrill What were
match checkhead you tap
matchwait

checkhead:
pause 2
put tap arrowhead in my %2
match nohead What were
match check7%7 You tap
matchwait

check6no:
goto check7%7

check7yes:
pause 2
put tap scribe in my %2
match noscribe What were
match start You tap
matchwait

#Pare the raw shaft

check7no:
start:
pause 2
put get my %1 from my %2
match checkknife Get what
match getshaft You remove
matchwait

checkknife:
pause 2
put glance
match getshaft down to see
match noknife empty hands
matchwait

getshaft:
pause 2
put get 1 shaft from my %2
pause 2
put cut my shaft with my %1
match badarrow You begin to pare
match paint%4 You pare away
matchwait

#Paint the shaft

paintyes:
pause 2
put put my %1 in my %2
pause 2
put get my paint from my %2
pause 2
put paint my shaft
pause 2
put put my paint in my %2
pause 2
goto band%5

paintno:
goto band%5

#Band the shaft

bandyes:
put get my paintstick from my %3

bandcont:
put paint my shaft
match waitpaints You should let the first coat of paint finish drying first
match goodband You carefully apply a band
matchwait

goodband:
pause 2
put put my paintstick in my %3
goto nockcheck

waitpaints:
waitfor The paint on your arrow shaft has dried
goto bandcont

bandno:
goto nockcheck

#Cut a nock

nockcheck:
pause 2
put get my %1 from my %2
pause 2
goto nock%4%5

nocknono:
put cut nocks in my shaft with my %1
match waitpaint You'd better wait 'til that paint dries
match okay should paint or crest
matchwait

nockyesno:
nocknoyes:
nockyesyes:
okay:
pause 2
put cut nocks in my shaft with my %1
match waitpaint You'd better wait 'til that paint dries
match measure You carefully cut
match badarrow You begin cutting
matchwait

waitpaint:
waitfor The paint on your arrow shaft has dried
goto nock%4%5

#Measure and cut the shaft

measure:
pause 2
put put my %1 in my %2
pause 2
put remove my bow
waitfor you remove

switch:
put swap
put measure my shaft with my bow
match switch Try holding the arrow shaft in your right hand
match measgood Nocking the arrow shaft
matchwait

measgood:
pause 2
put wear my bow
pause 2
put get my %1 from my %2
waitfor You remove
pause 2
put cut my sha with my %1
waitfor Using your previous mark
pause 2
put put my %1 in my %2
waitfor you put

#Fletch the shaft

feather:
pause 2
put get glue from my %2
pause 2
put put glue on my shaft
waitfor You carefully smea
pause 2
put put glue in my %2
pause 2
put get fletching from my %2
pause 2

havefletch:
pause 2
put put fletching on my shaft
match goodfletch You attach your
match tryagain are able to salvage the shaft
match badfletch discard the fletchings and shaft
matchwait

tryagain:
put put my fletching in my %2
goto feather

goodfletch:
put put my fletching in my %2

#Flip the shaft

flip:
pause 2
put flip my sha
match head%6 shaft color, followed by its material, followed by its projectile
match flip material, followed by its projectile style, followed by its shaft color
match flip material, followed by its shaft color, followed by its projectile
match flip shaft color, followed by its projectile style, followed by its material
matchwait

#Carve a tip

headno:
pause 2
put get my %1 from my %2
waitfor you remove

cutpoint:
pause 2
put cut my shaft with my %1
put cut my shaft with my %1
match goodcut With a few quick cuts
match badarrow Working a bit too hastily
match wait You'd better wait
matchwait

wait:
waitfor The glue on your arrow shaft has dried.
goto cutpoint

goodcut:
pause 2
put put my %1 in my %2
pause 2
goto scribe%7

#Add a metal arrowhead

headyes:
pause 2
put get drill from my %2
waitfor You remove
put turn drill
waitfor Setting the ti
pause 2
put put dril in my %2
pause 2
put get arrowh from %2
waitfor You remove
put turn arrowh
match goodarrow As you turn
match badhead As you go to turn
matchwait

goodarrow:
pause 2
goto scribe%7

#Scribe your symbol

scribeyes:
pause 2
put get scri from %2
pause 2
put rub scri on my arr
waitfor Using your scriber
put put scri in my %2

scribeno:
pause 2
echo Success, you now have a usable arrow. If you can only HIT something with it.
put appr my arrow
put put arr in arr in my %3
pause 2
goto checkshaft

badfletch:
pause 2
put put fle in my %2
echo Bad fletching, start over
goto checkshaft

badarrow:
pause 2
put put %1 in my %2
echo Bad arrow, start over
goto checkshaft

badhead:
pause 2
put put %1 in my %2
put put arrowh in my %2
echo Bad arrow, start over
goto checkshaft

noshaft:
pause 2
echo Out of shafts, need to get more
goto endit

noglue:
pause 2
echo Out of glue, need to get more
goto endit

nofletching:
pause 2
echo Out of fletchings, need to get more
goto endit

nopaint:
pause 2
echo Out of paint vials, need to get more
goto endit

nopaintstick:
pause 2
echo Out of paintsitcks, need to get more
goto endit

nodrill:
pause 2
echo You asked to put on arrowheads, where's your drill?
goto endit

nohead:
pause 2
echo Out of arrowheads, need to get more
goto endit

noscribe:
pause 2
echo You wanted to scribe your arrows, where's your scribe?
goto endit

endit:
exit

[Enuch]

Awesome thanks, but when I get there I may be asking you some more questions!