Warrior Guild Berserk Script WL (Old School)

[Tyronebiggums]

So here is the script im trying to work with on Avalon FE (don't ask). No Lich, and i need pauses in my scripts or they won't work, I am having trouble with missed berserks in the dark chamber, and going back to turn in the task. Any help would be appreciated.


#Berserk.cmd

Start:
pause .5
put Ask klidel about training Berserk
match start shy of earning your next rank."
match creatures berserk on some critter
match chamber practice breaking webbing.
match chamber practice breakin out of stuns."
match chamber that paralysis in no time.
match tubs a tub filled with ice
match saunas one of those saunas,
match promot Congratulations, you've earned a rank.
matchwait

creatures:
echo TIME FOR YOU TO DO SOME WORK DAMN YOU, BERSERK SOME CRITTERS!!!
exit

promot:
move Go door.
pause 1
move n
pause 1
move e
pause 1
move go door
pause 1
put Ask bert about next Berserk
pause 1
move Go door.
move w
pause 1
move s
move go door
pause 1
goto start

chamber:
move Go door.
move n
pause 1
move e
move go stair
pause 1
move w
put Stance offensive.
waitfor You
put Kneel
waitfor You
goto berserkchamber

berserkchamber:
put Berserk
match berserkdone [You have completed this task.]
match berserkwait Roundtime:
match berserkwait You feel yourself at the edge of berserker's rage but lose the moment.
match berserkwait The redness fades from the world
match berserkwait ...wait
matchwait

berserkwait:
pause 10
goto berserkchamber

berserkdone:
waitfor The redness fades from the world
put Stand
match allchamberdone You stand
match lastberserk You don't seem
match lastberserk You are still stunned.
match lastberserk You can't do that
matchwait

lastberserk:
waitfor Roundtime:
goto chamberstand

chamberstand:
put Stand
match allchamberdone You stand
match standwait ...wait
matchwait

standwait:
pause .5
goto chamberstand

allchamberdone:
put Stance defensive.
waitfor You
move e
pause 1
move go stair
move w
pause 1
move s
move go door
pause 1
goto Start

tubs:
move Go door.
move go n
pause 1
move go e
move go step
pause 1
move go w
move go tub
pause 1
put Stance offensive.
waitfor You
goto tubssplash

tubssplash:
put Splash
match berserktub You even seem to have quit shivering.
match tubssplash Roundtime:
match splashwait ...wait
matchwait

splashwait:
pause .5
goto tubssplash

berserktub:
put Berserk
match berserktubwait repetition(s) remaining.]
match berserktubwait Roundtime:
match berserktubwait ...wait
match tubssplash Try splashing around a bit first.
match tubsdone [You have completed this task.]
matchwait

berserktubwait:
pause .5
goto berserktub

tubsdone:
put stand
waitfor You stand
put Stance defensive.
waitfor You
move out
pause 1
move Go e
move go step
pause 1
move go w
move go s
pause 1
move go door
goto Start

saunas:
move go e
move Go e
pause 1
move go sauna
put Stance offensive.
waitfor You
goto meditate

meditate:
put Meditate
match berserksauna slip into a fit of rage quite easily
match meditate Round time:
match meditatewait ...wait
matchwait

meditatewait:
pause .5
goto meditate

berserksauna:
put Berserk
match berserksaunawait repetition(s) remaining.]
match berserksaunawait Roundtime:
match berserksaunawait ...wait
match saunadone [You have completed this task.]
matchwait

berserksaunawait:
pause .5
goto berserksauna

saunadone:
put Stand
waitfor You stand
put Stance defensive.
waitfor You
move out
move go gl door
move go arch door
goto start

[gs4-PauperSid]

I feel your pain regarding avalon/no lich.

Anyhow, this is the script I used. Dont think it's perfect either, but may help you trouble shoot yours, or tweek this one. Again, not my creation.

-j

mainloop:
put ask klid about train berserk
pause
put ask klid about train berserk
match again all done with that task
match tub1 filled with ice
match critter challengin for your skill
match chamber Dark Chamber
match sauna saunas
match ranked promoted
match gottask Each time you trade in a task
matchwait

ranked:
put go door
move n
move e
put go door
put ask bert about next berserk
put go door
move w
move s
put go door
goto mainloop

gottask:
put gld
match sauna saunas
match tub1 ice tubs
match critter practice Berserk against creatures
match chamber Dark Chamber
matchwait

darkroom:
pause 3
put berserk
match darkroom Dark thoughts of battle
match darkroom You can taste the bloodlust in the back
match darkroom You feel yourself at the edge of
match darkroom breathe harder
match darkroom snapping you out
match darkroom letting you move freely
match darkroom slowly fades
match chamberdone though you obviously
matchwait

chamberdone:
put stand
pause 5
move e
move go stair
move w
move s
move go door
goto mainloop

again:
goto mainloop

tub1:
put go door
move n
move e
put go step
move w
put go tub
goto tub2

tub2:
put splash
match splashfail raises your body temperature
match splashgood even seem to have quit
matchwait

splashfail:
goto tub2

splashgood:
put berserk
match tired1 beginning to feel a little fatigued
match tubagain Dark thoughts of battle quickly fill your
match tubagain You feel yourself at the edge of
match tubagain You can taste the bloodlust in the back
match tubagain remaining.]
match tubdone completed this task.]
matchwait

tired1:
waitfor energetic
goto splashgood

tubagain:
goto splashgood

tubdone:
put stand
pause 5
move out
move e
put go step
move w
move s
put go door
goto mainloop

critter:
pause 1
Echo **********************************
Echo TIME TO GO BERSERK ON MONSTERS....
Echo **********************************
exit

chamber:
put go door
move n
move e
put go stair
move w
put kneel
goto darkroom

sauna:
move e
move e
put go sauna
goto sauna1

sauna1:
put meditate
match saunafail deal with the trifles
match saunagood quite easily now
matchwait

saunafail:
pause 1
goto sauna1

saunagood:
put berserk
match saunaagain Dark thoughts of battle quickly fill
match saunaagain You can taste the bloodlust in the back
match saunaagain You feel yourself at the edge of
match tired2 beginning to feel a little fatigued
match saunaagain remaining.]
match saunadone completed this task.]
matchwait

saunaagain:
goto saunagood

saunadone:
put stand
pause 5
move out
move w
move w
goto mainloop

tired2:
waitfor energetic
goto saunagood